Android rom解包打包工具

eMMC主要是針對手機和平板電腦等產品的內嵌式存儲器，由於其在封裝中集成了一個控制器，且提供標准接口並管理閃存等優勢，越來越受到Android手機廠商的青睐，以eMMC為存儲設備的android手機，其文件系統（system、data分區）一般采用ext4格式。如小米手機的線刷包：

一.img解包

之前我在修改小米桌面中介紹過利用rom助手解包。

這裡介紹另一個更方便實用的工具：windows平台的ext4_unpacker。

直接選擇需要解壓的img鏡像文件，然後extract所有文件即可。同樣，解壓出來後可對rom進行精簡，刪除一些不需要的app。

二.img打包

這裡利用make_ext4fs來對解壓出來的文件進行打包。

使用說明：將下載下來的make_ext4fs.exe拷貝到C:\WINDOWS目錄下，其他dll文件，拷貝到C:\Windows\System32目錄下。

主要參數說明：

-l <limit size>:表示最大的文件大小，受限於system或data分區的大小。

-a <system/data>:表示Android的mount點，將img文件系統掛在到安卓手機的system/data文件夾下。

-S file_contexts:表示sepolicy的file_contexts，5.0及以上安卓系統存在file_contexts文件，該文件是對selinux文件系統的說明，在手機root目錄下能找到。

-s:表示對img文件進行壓縮，去除img文件系統空白部分，得到數據文件占用空間的真實大小。

-T:表示Unix時間戳，對img文件設置修改時間，可用在站長之家轉換需要的時間戳。

<filename>:表示輸出的文件名。

<directory>:表示輸入的文件目錄。

補充說明：

1）-l <limit size>中limit size大小單位為M，該值的大小受限於分區大小，如果制作出來的鏡像大小大於該值，將會提示失敗。對於分區的大小可以通過df命令獲得。

2）用pull命令對手機中的file_contexts文件進行提取

先查看該系統中是否有file_contexts文件，再pull出該文件。

OK，現在我們就可以對文件進行打包了。

make_ext4fs -S file_contexts -s -l 3072M -a system system.img ./system

三.批處理腳本實現快速定制rom包

也許做過rom的都知道：

1.對於4.4系統的手機，如果要打入apk到system區，只需將apk復制到system/app下，對應apk的lib文件（.so文件）復制到system/lib下即可；如果要打入apk到userdata區，只需將apk復制到userdata/app下即可。

2.對於5.0及以上系統的手機，如果要打入apk到system區，需要將apk及對應的lib文件建在同一目錄下，然後復制到system/app下（具體查看system/app下其他apk的目錄格式），並且，在實踐中，有的手機需要打入到system/framework中apk才能正常運行，不然閃退；如果需要打入apk到userdata區，同樣只需將apk復制到userdata/app下即可。

幾點說明：

1.由於需要解壓出apk下的lib文件，而且，用winrar帶的rar和unrar並不支持apk格式，所以用了好壓的解壓功能。將好壓的安裝目錄配置到系統的path環境即可。這樣就可以在命令行調用HaozipC命令，在安裝目錄下也有命令行的說明文檔，具體可自行安裝查看。

2.由於有的手機需要打入system/framework中apk才能正常啟動，因此在批處理時加入手動選擇是否打入。

3.對於系統分區限制大小，可以先df出，存入txt列表中，讓腳本自動讀取。如：

4.實踐中，5.0及以上系統，打入system區的apk可能不能包含中文名字。避免頻繁更改，同樣可以建一個txt文件，讓腳本自動更改。如：

5.對於5.0及以上系統請先pull file_contexts文件到當前目錄。

批處理腳本如下：makeRom.zip（下載）

@echo off
title 定制rom包 by 小猴子jerry
echo -------------------------------------------------------------------------
echo 注意：請務必輸入正確的安卓系統和底包編號，否則做包無效
echo 安卓系統（4.4/5.0）、底包編號（01等）
echo 安卓系統5.0及以上請輸入5.0
echo -------------------------------------------------------------------------
pause
set /p version=請輸入安卓系統版本號(4.4/5.0):
set /p var=請輸入底包編號:
if exist .\sysApk set /p is_framework=是否需要打入apk到framework中(y/n):
echo ----------------請仔細核對，若輸入有誤請關閉程序重新輸入-----------------
pause
if %version%==4.4 (
%打包system%
if exist .\system (
echo system.img正在制作中...
if exist .\sysApk (
echo 正在解壓需要的.so文件...
for /f "delims=" %%a in ('dir /b/a-d/oN .\sysApk\*.*') do (
HaoZipC x .\sysApk\%%a -o.\syslib lib\armeabi\*.* -y -sn)
copy sysApk\*.* system\app
move syslib\lib\armeabi\*.* system\lib
rd/s/q syslib)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -s -l %%j -a system ./system.img ./system
)
echo system.img制作完成)
%打包userdata%
if exist .\userdata (
echo userdata.img正在制作中...
if exist .\userApk (
if not exist userdata\app ( md userdata\app )
copy userApk\*.* userdata\app)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -s -l %%k -a data ./userdata.img ./userdata
)
echo userdata.img制作完成)
if not exist .\system (
if not exist .\userdata (
echo 找不到system or userdata文件夾，請拷貝system或userdata到當前目錄))
%處理update文件%
if not exist .\update.rom (
echo 找不到update文件，請拷貝update.rom到當前目錄)
if exist .\update.rom (
ren update.rom update.zip
HaoZipC d -tzip update.zip -ri!images\system images\userdata -sn
if not exist .\images ( md .\images )
if exist .\system.img ( move system.img .\images)
if exist .\userdata.img ( move userdata.img .\images)
HaoZipC a -tzip update.zip .\images\ -sn)
ren update.zip update.rom
rd/s/q system
rd/s/q userdata
rd/s/q images
echo 定制rom包制作完成！！)
rem =========================================================================================================================
if %version%==5.0 (
%前提：從手機中pull出需要的file_contexts文件%
%打包system%
if exist .\system (
echo system.img正在制作中...
if exist .\sysApk (
echo 正在解壓需要的.so文件...
for /f "tokens=1,2 delims=." %%a in ('dir /b/a-d/oN .\sysApk\*.*') do (
if %%a==usbhelp ( ren .\sysApk\usbhelp.apk com.service.usbhelper.apk
md .\syslib\com.service.usbhelper
move .\sysApk\com.service.usbhelper.apk .\syslib\com.service.usbhelper)
for /f "tokens=1,2 delims=:" %%i in (AppList.txt) do ( 
if %%a==%%i ( ren .\sysApk\%%a.apk %%j.apk
HaoZipC x .\sysApk\%%j.apk -o.\syslib\%%j lib\armeabi\*.* -y -sn
ren .\syslib\%%j\lib\armeabi arm
move sysApk\%%j.apk syslib\%%j)))
if %is_framework%==y ( xcopy/s/y syslib system\framework) else (
xcopy/s/y syslib system\app)
rd/s/q syslib)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -S file_contexts -s -l %%j -a system ./system.img ./system)
echo system.img制作完成)
%打包userdata%
if exist .\userdata (
echo userdata.img正在制作中...
if exist .\userApk (
if not exist userdata\app ( md userdata\app )
move userApk\*.* userdata\app)
for /f "skip=1 tokens=1,2,3" %%i in (limit.txt) do ( 
if %%i==%var% make_ext4fs -S file_contexts -s -l %%k -a data ./userdata.img ./userdata)
echo userdata.img制作完成)
del file_contexts
if not exist .\system (
if not exist .\userdata (
echo 找不到system or userdata文件夾，請拷貝system或userdata到當前目錄))
%處理update文件%
HaoZipC d -tzip update.zip -ri!images\system images\userdata -sn
if not exist .\images ( md .\images )
if exist .\system.img ( move system.img .\images)
if exist .\userdata.img ( move userdata.img .\images)
HaoZipC a -tzip update.zip .\images\ -sn
ren update.zip update.rom
rd/s/q system
rd/s/q userdata
rd/s/q images
rd/s/q sysApk
rd/s/q userApk
echo 定制rom包制作完成！！)
pause 

注意：

目錄設置為如下：

運行bat：

通過本文的學習，又一次復習了常用的命令行命令，同時也希望本文所述對大家也有所幫助。